reversing text

strTest = "asp is fun to program"
aString = Split(strTest, " ")
For i = 0 To Ubound(aString)
   aString(i) = strReverse(aString(i))
Next
strTest = Join(aString, " ")

<% Option Explicit
'dump the whole text in a variable
'search in the variable for <p and > and </p> (InStr)
'Split the in between text delimiter space
'Loop through the split array and search for ASC 224 - ASC 251
'If there are characters in that array element, reverse
'Join Array and add to the output variable

Dim strInput 'input string
Dim strOut   'output string
Dim aPar, i, j 'word split and indexes for loops
Dim intCurrentPosition 'where are we in the text
Dim intParTag, intParTagLength 'what position starts the <p> tag and how long
Dim intParCloseBracket  'what position ends the <p> tag
Dim intParEndTag 'what position start the </p> tag
Dim bNeedReversal 'flag to determine whether reversal is needed or not

'your input string
strInput = ""

'initialize output string
strOut = ""

'start at the beginning of the text file
intCurrentPosition = 1

'loop thru the text file
Do While Not intCurrentPosition > Len(strInput)
  'position of the paragaph tag
  intParTag = inStr(intCurrentPosition, strInput, "<p", 1)
  If intParTag > 0 Then  'found a pararagh tag
    'end position of the paragraph tag (<p> is smaller then <p align="left"> ;))
	intParCloseBracket = inStr(intParTag, strInput, ">", 1)
	
	'start position of the end paragraph tag
	IntParEndTag =  inStr(intParCloseBracket, strInput, "</p>", 1)
  Else  'did not found a par tag
	intParEndTag = 0
  End If
  
  If intParTag = 0 Or intParEndTag = 0 Then 'exit routine to grab the remaining document
	strOut = strOut & Mid(strInput, intCurrentPosition + 1, Len(strInput) - (intCurrentPosition -1))    
  	Exit Do
  ElseIf intCurrentPosition = 1 Then 'grab the beginning of the document
    strOut = strOut & Mid(strInput, intCurrentPosition, intParTag - 1)
  End If
  
  'add paragraph tag
  intParTagLength = IntParCloseBracket - (intParTag - 1) 'how long is the tag?
  strOut = strOut & Mid(strInput, intParTag, intParTagLength)

  'split the paragraph text into words
  aPar = Split(Mid(strInput, intParCloseBracket + 1, (intParEndTag - 1) - intParCloseBracket), " ")
  
  'loop thru words
  For i = 0 To Ubound(aPar)
    'do we need to reverse flag
    bNeedReversal = True
    For j = 1 To Len(aPar(i))  'loop thru characters of each word
      If Asc(Mid(aPar(i), j, 1)) < 224 Or Asc(Mid(aPar(i), j, 1)) > 251 Then
         'english characters or HTML characters
	     bNeedReversal = False
	     Exit For
             End If  'asc test
    Next 'j
    
    'reverse word only when reversal flag is set
    If bNeedReversal Then aPar(i) = strReverse(aPar(i))
    
  Next 'i
  
  'paste all the words back together
  strOut = strOut & Join(aPar, " ")
  
  'add end paragrap tag
  strOut = strOut & mid(strInput, intParEndtag, 4)
  
  'move the currentposition up to new paragraph
  intCurrentPosition = intParEndTag + 3
Loop

Response.Write strOut 'display final result
%>